// jjaf.de combat messages

ECHO "--- jjaf.de combat messages 1.3.1 --"
ECHO "update on http://jjaf.de/kingpin/messaging"

// Format: [COUNT] + [PERSON] + [AREA] + [POINT] + [DIRECTION] + [INTENTION] + [TIME]

// WEAPON REDIRECTION -----
ECHO " -WEAPON REDIRECTION"
bind F1 "use pipe"
bind F2 "use pistol"
bind F3 "use shotgun"
bind F4 "use tommygun"
bind F5 "use heavy machinegun"
bind F6 "use grenade launcher"
bind F7 "use bazooka"
bind F8 "use flamethrower"
bind F10 "menu_quit"
bind F11 "screenshot"
bind F12 "cmd help"

// DEFAULTS
ECHO " -COUNT"
SET ResetValue "-"

// COUNT -----
ECHO " -COUNT"
SET COUNTdefault "1"
ALIAS COUNTreset SET COUNT "$ResetValue"
BIND 0 "SET COUNT NONE; msgprv"
BIND 1 "SET COUNT 1; msgprv"
BIND 2 "SET COUNT 2; msgprv"
BIND 3 "SET COUNT 3; msgprv"
BIND 4 "SET COUNT 4; msgprv"
BIND 5 "SET COUNT 5; msgprv"
BIND 6 "SET COUNT 6; msgprv"
BIND 7 "SET COUNT 7; msgprv"
BIND 8 "SET COUNT 8; msgprv"
BIND 9 "SET COUNT ALL; msgprv"

// PERSON -----
ECHO " -PERSON"
SET PERSONdefault "ENEMY"
ALIAS PERSONreset "SET PERSON $ResetValue"
BIND ] "SET PERSON ALLY; msgprv"
BIND \ "SET PERSON ENEMY; msgprv"

// AREA
ECHO " -AREA"
SET AREAdefault "@ALLY-"
SET AREAcurr "@ALLY-"
SET AREA "@ALLY-"
ALIAS AREAreset "SET AREA $ResetValue"
ALIAS +AREAshift "SET AREAcurr @ENEMY-"
ALIAS -AREAshift "SET AREAcurr @ALLY-"
BIND KP_INS "+AREAshift"

// POINTS -----
ECHO " -POINTS"
EXEC points-std.txt

// DIRECTION -----
ECHO " -DIRECTION"
SET DIRECTIONdefault "-"
ALIAS DIRECTIONreset "SET DIRECTION $ResetValue"
BIND KP_SLASH "SET DIRECTION <IN<; msgprv"
BIND * "SET DIRECTION >OUT>; msgprv"

// INTENTION -----
ECHO " -INTENTION"
SET INTENTIONdefault "-"
ALIAS INTENTIONreset "SET INTENTION $ResetValue"
BIND - "SET INTENTION RAID; msgprv"
BIND [ "SET INTENTION COLLECT; msgprv"
BIND ' "SET INTENTION CAMP; msgprv"
BIND p "SET INTENTION ROBBER-ESC; msgprv"
BIND ";" "SET INTENTION GUARD; msgprv"
BIND / "SET INTENTION DEPOSIT; msgprv"
BIND KP_PLUS "SET INTENTION ACK; COUNTreset; PERSONreset; AREAreset; POINTreset; SET TIMEVAL 5s; msgprv"
BIND KP_MINUS "SET INTENTION NAK; COUNTreset; PERSONreset; AREAreset; POINTreset; TIMEVALreset; msgprv"

// TIME -----
ECHO " -TIME"
SET TIMEVALdefault "-"
ALIAS TIMEVALreset "SET TIMEVAL $ResetValue"
BIND PAUSE "TIMEVALreset; msgprv"
BIND END "SET TIMEVAL NOW; msgprv"
BIND PGDN "SET TIMEVAL 5s; msgprv"
BIND PGUP "SET TIMEVAL 10s; msgprv"
BIND HOME "SET TIMEVAL wait-for-me; msgprv"

// STORNO -----
ECHO " -STORNO"
BIND B_SPACE "msgrst; SAY_TEAM = STORNO $COUNT $PERSON $AREA $POINT $DIRECTION $INTENTION $TIMEVAL =; msginit"

// REQUEST -----
ECHO " -REQUEST"
BIND = "SAY_TEAM * REQUESTING INFO ON $POINT $TIMEVAL *"

// RESTORE -----
ECHO " -RESTORE"
BIND KP_DEL "msgrst; msgprv"

// SPECIAL SITUATIONS -----
ECHO " -SPECIAL SITUATIONS"
BIND i "COUNTreset; SET PERSON ENEMY; SET DIRECTION <IN<; SET INTENTION RAIDING; msgprv"
// WORKAROUND: do not insert spaces, bind string will be too long!
BIND o "COUNTreset; PERSONreset ;SET AREA @;SET POINT near;SET DIRECTION <IN<;SET INTENTION DEPOSITING;SET TIMEVAL 5s; msgprv"
BIND h "SET PERSON CASH; SET AREA @; SET POINT MONEYDROP; DIRECTIONreset; COUNTreset; msgprv"

// MSG-PREVIEW -----
ECHO " -MSG-PREVIEW"
// choose one of these to en-/disable message-preview
ALIAS msgprv "ECHO # $COUNT $PERSON $AREA $POINT $DIRECTION $INTENTION $TIMEVAL #"
//### ALIAS msgprv ""

// INIT -----
ECHO " -INIT"

BIND KP_ENTER msgsend

ALIAS msgsend "SAY_TEAM # $COUNT $PERSON $AREA $POINT $DIRECTION $INTENTION $TIMEVAL #; msgarc; msginit"

ALIAS msginit "msgini1; SET DIRECTION $DIRECTIONdefault; SET INTENTION $INTENTIONdefault; SET TIMEVAL $TIMEVALdefault"
ALIAS msgini1 "SET COUNT $COUNTdefault; SET PERSON $PERSONdefault; SET POINT $POINTdefault; SET AREA $AREAdefault"

ALIAS msgarc "msgarc1; SET DIRECTIONarc $DIRECTION; SET INTENTIONarc $INTENTION; SET TIMEVALarc $TIMEVAL"
ALIAS msgarc1 "SET COUNTarc $COUNT; SET PERSONarc $PERSON; SET POINTarc $POINT; SET AREAarc $AREA"

ALIAS msgrst "msgrst1; SET DIRECTION $DIRECTIONarc; SET INTENTION $INTENTIONarc; SET TIMEVAL $TIMEVALarc"
ALIAS msgrst1 "SET COUNT $COUNTarc; SET PERSON $PERSONarc; SET POINT $POINTarc; SET AREA $AREAarc"

msginit

// READY -----
ECHO "------------------------------------"